tech note

需要がありそうなわりに意外と情報が少ないイナズマ線の描画方法。
フリーのガントチャートツールはVBAコードが公開されてなかったりするので、ここに書いておきます。
※動作確認してるのは、Excel2000～2003くらいまでです。
- - -

↓こういうのを引く例


Public Sub DrawInazuma()
  Dim sx As Single, sy As Single  '開始点
  Dim mx As Single, my As Single  '中間点
  Dim ex As Single, ey As Single  '終了点
  Dim nl As Shape

  With Sheet1
    '縦に１本引く・・・（下記 解説１）
    sx = .Range("B1").Left
    sy = .Range("B1").Top
    ex = .Range("B9").Left
    ey = .Range("B9").Top
    Set nl = .Shapes.AddLine(sx, sy, ex, ey)
    With nl.Line
      .DashStyle = msoLineSolid        'スタイル
      .Weight = 2                      '太さ
      .ForeColor.RGB = RGB(255, 0, 0)  '色
    End With
    '折り曲げる節点を指定していく
    '折り曲げその１・・・（下記 解説２）
    sx = .Range("B2").Left
    sy = .Range("B2").Top
    mx = .Range("A3").Left
    my = .Range("A3").Top
    ex = .Range("B4").Left
    ey = .Range("B4").Top
    With nl
      .Nodes.Insert .Nodes.Count - 1, _
              msoSegmentLine, msoEditingAuto, sx, sy
      .Nodes.Insert .Nodes.Count - 1, _
              msoSegmentLine, msoEditingAuto, mx, my
      .Nodes.Insert .Nodes.Count - 1, _
              msoSegmentLine, msoEditingAuto, ex, ey
    End With

    '折り曲げその２・・・（下記 解説３）
    sx = .Range("B5").Left
    sy = .Range("B5").Top
    mx = .Range("C6").Left
    my = .Range("C6").Top
    ex = .Range("B7").Left
    ey = .Range("B7").Top
    With nl
      .Nodes.Insert .Nodes.Count - 1, _
              msoSegmentLine, msoEditingAuto, sx, sy
      .Nodes.Insert .Nodes.Count - 1, _
              msoSegmentLine, msoEditingAuto, mx, my
      .Nodes.Insert .Nodes.Count - 1, _
              msoSegmentLine, msoEditingAuto, ex, ey
    End With
  End With
End Sub


1. まず縦に１本線を引く

まず上から下まで１本線を引きます。ガントチャートなら現在の日付になるでしょう。
線を引くには、Worksheet.Shapes#AddLineメソッドに開始点のX座標とY座標、終了点のX座標とY座標を指定します。座標を得るにはLeftプロパティやTopプロパティを用います。
AddLineメソッドからは新しい線のShapeオブジェクトが返されるので、Lineプロパティに線の種類や太さや色を指定します。
この時点で線は以下のようになります。


2. 折り曲げその１

ガントチャートで進捗が遅れている場合には、イナズマ線を左に曲げる必要があります。
折り曲げるには、折り曲げ「開始点・中間点・終了点」の３点が必要です。
この例では、開始点=B2の左上、中間点=A3の左上、終了点=B4の左上、としています。
Shape.Nodes#Insertメソッドをそれぞれ３点で呼び出せば、以下のようになります。


3. 折り曲げその２

逆に進捗が進んでいる場合には、イナズマ線を右へ曲げる必要があります。
これも同様に「開始点・中間点・終了点」の３点を指定するだけです。
開始点=B5の左上、中間点=C6の左上、終了点=B7の左上。
で、こうなります。